Arduino库教程-SD-Datalogger

Using the SD library to log data

• 这个例子展示了如何使用SD卡库把三个模拟传感器的数据登录到SD卡。请点击这里了解更多关于SD卡的信息。

硬件要求

• Arduino or Genuino board
• Ethernet Shield (或者其他有SD插槽的开发板)
• 3 10k ohm 电位计
• 连接线
• 面包板
• 格式化的 SD card

电路

图由 Fritzing 软件绘制

• Arduino或genuino板必须连接到Ethernet Shield。三个电位器可以被其他模拟传感器取代，连线是根据他们的接口技术。

原理图

图由 Fritzing 软件绘制

样例代码

• 下面的代码被配置为使用一个Ethernet shield，上面有一个板上SD卡插槽。在setup()里，调用SD.begin()，命名pin4为CS引脚。此引脚的变化取决于你正在使用的shield或开发板的制作。

• 在loop()里，创建一个字符串来保存来自三个模拟传感器的信息。代码扫描所有传感器，添加他们的数据到字符串里。

• 然后，调用SD.open()打开SD卡的文件。一旦有效，当使用dataFile.println() 时，数据被写入到SD卡里。该文件必须用dataFile.close()封闭以便保存其信息。

/*
  SD card datalogger

 This example shows how to log data from three analog sensors
 to an SD card using the SD library.

 The circuit:
 * analog sensors on analog ins 0, 1, and 2
 * SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 4

 created  24 Nov 2010
 modified 9 Apr 2012
 by Tom Igoe

 This example code is in the public domain.

 */

#include <SPI.h>
#include <SD.h>

const int chipSelect = 4;

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }


  Serial.print("Initializing SD card...");

  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    return;
  }
  Serial.println("card initialized.");
}

void loop() {
  // make a string for assembling the data to log:
  String dataString = "";

  // read three sensors and append to the string:
  for (int analogPin = 0; analogPin < 3; analogPin++) {
    int sensor = analogRead(analogPin);
    dataString += String(sensor);
    if (analogPin < 2) {
      dataString += ",";
    }
  }

  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
  File dataFile = SD.open("datalog.txt", FILE_WRITE);

  // if the file is available, write to it:
  if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    // print to the serial port too:
    Serial.println(dataString);
  }
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  }
}

[Get Code]
更多

• SD library - SD 卡库的参考网页.

• Notes on using SD cards – 当你使用SD卡时，你需要知道什么

• Datalogger - 如何把三个模拟传感器的数据记录到SD卡。

• DumpFile - 怎样从SD卡里读取一个文件。

• Files - 怎样创建和删除一个SD卡文件。

• Listfiles - 怎样将SD卡上的目录中的文件打印出来。

• ReadWrite - 怎样从一个SD卡里读取或写入文件